*       SUPPLEMENTAL CODING TO GENERATE 1999 CRIME COUNTS.
*
*       Counts are generated on a "data year" (6 quarters ) basis.
* NOTE: BJS ANNUAL PUBLICATIONS USE COLLECTION YEAR FORMAT (NOT DATA YEAR FORMAT.)

* THE GET FILE STATEMENT ASSUMES THAT AN INCIDENT-LEVEL FILE WAS
* PREVIOUSLY CREATED AND SAVED USING THE 1999 FULL HIERARCHICAL FILE.
* IT WAS SAVED UNWEIGHTED.
get file "C:\NCVS\incident99.sav".

* SELECT CASES THAT ARE NON-SERIES CRIMES.
* V4019 = ENOUGH DETAIL TO DISTINGUISH INCIDENTS.
select if (v4019 ne 2).

* SELECT CASES WHERE CRIMES OCCURRED IN THE UNITED STATES ONLY.
* V4022 = IN WHAT CITY TOWN, VILLAGE.
select if (v4022 ne 1).

* "BOUND" THE OCCURRENCE OF CRIMES INTO 1999 CALENDAR YEAR.
*        V4003 = YEAR AND QUARTER IDENTIFICATION
*        V4014 = MONTH INCIDENT OCCURRED
*.
select if (any(v4003,991,992) and any(v4014,1,2,3,4,5,6)) or
             any(v4003,993,994) or
            (any(v4003,001,002) and any(V4014,6,7,8,9,10,11,12)).

* IF THE TYPE OF CRIME IS ONE OF THE HOUSEHOLD CRIMES THEN SET THE
* TEMPORARY WEIGHT VARIABLE 'ADJWGT' TO THE HOUSEHOLD WEIGHT.
*         V2116 = HOUSEHOLD WEIGHT
*         V4529 = TOC CODE (NEW, NCVS)
*
* IF THE TYPE OF CRIME IS ONE OF THE PERSONAL CRIMES THEN SET THE
* TEMPORARY WEIGHT VARIABLE 'ADJWGT' TO THE PERSON WEIGHT.
*         V3080 = PERSON WEIGHT
*         V4529 = TOC CODE (NEW, NCVS)
*.

do if (v4529 gt 23).
compute adjwgt=v2116.
else if (v4529 le 23).
compute adjwgt=V3080.
end if.

* RECODE TYPE OF CRIME VARIABLE (V4529) INTO CRIME CATEGORIES TYPICALLY USED BY BJS.
* CREATE VARIABLE AND VALUE LABELS.  

recode v4529
        (1 = 1)                      /* rape
        (2,18 = 2)                   /* attempted rape
        (3,4,15,16,19 = 3)           /* sexual  assault 
        (5,6  = 4)                   /* completed robb w injury
        (7 = 5)                      /* completed robb wo injury
        (8,9 = 6)                    /* attempted robb w injury
        (10 = 7)                     /* attempted robb wo injury
        (11 = 8)                     /* agg aslt with injury
        (12,13 = 9)                  /* agg aslt threat w weapon
        (14 = 10)                    /* simple aslt minor injury
        (17,20 = 12)                 /* simple assault wo injury
        (21,22,23 = 13)              /* personal theft
        (31 = 14)                    /* burg force entry
        (32 = 15)                    /* unlawful entry wo force
        (33 = 16)                    /* attempt force entry
        (40 = 17)                    /* completed motor vehicle theft
        (41 = 18)                    /* attempted motor vehicle theft
        (54,55 = 19)                 /* theft < $50
        (56 = 20)                    /* theft $50 - $249
        (57 = 21)                    /* theft $250
        (58 = 22)                    /* theft value N/A (count added with total completed thefts)
        (59 = 23)                    /* theft attempted 
        into crimes.

variable labels crimes "CATEGORIES OF CRIME IN TABLE 1".

value labels crimes
    1 "Rape"
    2 "Att rape"
    3 "Sexual assault"
    4 "Comp robb w injury"
    5 "Comp robb wo injury"
    6 "Att robb w injury"
    7 "Att robb wo injury"
    8 "Agg aslt w injury"
    9 "Agg aslt thrt w weapon"
   10 "Simple aslt minor inj"
   12 "Simple assault wo inj"
   13 "Personal theft"
   14 "Burg force entry"
   15 "Unlawful entry wo force"
   16 "Attempt force entry"
   17 "Comp motor vehicle theft"
   18 "Att motor vehicle theft"
   19 "Theft < $50"
   20 "Theft $50 - $249"
   21 "Theft $250"
   22 "Theft value N/A"
   23 "Theft attempted"
.

* WEIGHTED FREQUENCY DISTRIBUTION FOR TYPE OF CRIME (V4529)
* CATEGORIES OF CRIME (CRIMES).
weight by adjwgt.
freq vars = v4529 crimes.