* SUPPLEMENTAL CODING TO GENERATE 1999 VICTIMIZATION COUNTS.
*
* COUNTS ARE GENERATED ON A "COLLECTION YEAR" (4 QUARTERS ) BASIS.
* SEE BJS PUBLICATION - "CRIMINAL VICTIMIZATION 1999 CHANGES 1998-99
* WITH TRENDS 1993-99".

* THE GET FILE STATEMENT ASSUMES THAT AN INCIDENT-LEVEL FILE WAS
* PREVIOUSLY CREATED AND SAVED USING THE 1999 FULL HIERARCHICAL FILE.
* IT WAS SAVED UNWEIGHTED.
get file = "C:\NCVS\incident99.sav".

* SELECT ONLY THE FOUR COLLECTION QUARTERS OF 1999.
* EXCLUDE QUARTERS 1 AND 2 OF 2000.
* V4003 = YEAR AND QUARTER IDENTIFICATION.
select if ( any(V4003,991,992,993,994) ).

* SELECT CASES THAT ARE NON-SERIES CRIMES.
* V4019 = ENOUGH DETAIL TO DISTINGUISH INCIDENTS.
select if (v4019 ne 2).

* EXCLUDE CRIMES OUTSIDE THE U.S. ( RECOMMENDED ).
* V4002 = IN WHAT CITY, TOWN, VILLAGE.
select if ( v4022 ne 1 ).

* WEIGHT THE FILE.
* ADJUST WEIGHTS SO THAT FILE IS WEIGHTED
* BY PERSON WEIGHT (V3080) FOR CRIMES AGAINST PERSONS,
* AND BY HOUSEHOULD WEIGHT (V2116) FOR CRIMES AGAINST HOUSEHOLDS.
* V4529 = TYPE OF CRIME CODE.
do if (range(v4529,1,23)).
compute adjwgt=v3080.
else if (range(v4529,31,59)).
compute adjwgt=v2116.
end if.
weight by adjwgt.

* RECODE TYPE OF CRIME VARIABLE (V4529) INTO CRIME CATEGORIES AS THEY
* APPEAR IN TABLE 1 OF "CRIMINAL VICTIMIZATION 1999 CHANGES 1998-99
* WITH TRENDS 1993-99".
* CREATE VARIABLE AND VALUE LABELS.

recode v4529
  (1 = 1)                    /* rape
  (2,18 = 2)                 /* attempted rape
  (3,4,15,16,19 = 3)         /* sexual assault
  (5,6 = 4)                  /* completed robb w injury
  (7 = 5)                    /* completed robb wo injury
  (8,9 = 6)                  /* attempted robb w injury
  (10 = 7)                   /* attempted robb wo injury
  (11 = 8)                   /* agg aslt with injury
  (12,13 = 9)                /* agg aslt threat w weapon
  (14 = 10)                  /* simple aslt minor injury
  (17,20 = 12)               /* simple assault wo injury
  (21,22,23 = 13)            /* personal theft
  (31 = 14)                  /* burg force entry
  (32 = 15)                  /* unlawful entry wo force
  (33 = 16)                  /* attempt force entry
  (40 = 17)                  /* completed motor vehicle theft
  (41 = 18)                  /* attempted motor vehicle theft
  (54,55 = 19)               /* theft < $50
  (56 = 20)                  /* theft $50 - $249
  (57 = 21)                  /* theft $250
  (58 = 22)                  /* theft value N/A (count added with total completed thefts)
  (59 = 23)                  /* theft attempted 
  into crimes.

variable labels crimes "CATEGORIES OF CRIME IN TABLE 1".

value labels crimes
  1 "Rape"
  2 "Att rape"
  3 "Sexual assault"
  4 "Comp robb w injury"
  5 "Comp robb wo injury"
  6 "Att robb w injury"
  7 "Att robb wo injury"
  8 "Agg aslt w injury"
  9 "Agg aslt thrt w weapon"
  10 "Simple aslt minor inj"
  12 "Simple assault wo inj"
  13 "Personal theft"
  14 "Burg force entry"
  15 "Unlawful entry wo force"
  16 "Attempt force entry"
  17 "Comp motor vehicle theft"
  18 "Att motor vehicle theft"
  19 "Theft < $50"
  20 "Theft $50 - $249"
  21 "Theft $250"
  22 "Theft value N/A"
  23 "Theft attempted"
.

* WEIGHTED FREQUENCY DISTRIBUTION FOR TYPE OF CRIME (V4529)
* CATEGORIES OF CRIME (CRIMES).
weight by adjwgt.
freq vars = v4529 crimes.